@echo off
chcp 65001 >nul
setlocal
title Quick Support - VALID.CZ
set "SERVER=https://cloud.valid.cz/f/fb976eb0171144b7b584/?dl=1"
fltmc >nul 2>&1
if errorlevel 1 (
    echo Potřebuji oprávnění správce, vyžádám si je...
    powershell -NoProfile -Command "Start-Process -FilePath \"%~f0\" -Verb RunAs"
    if errorlevel 1 (
        echo.
        echo "====> Chyba A <====" 
        echo ABez oprávnění správce není možné QuickSupport spustit.
        echo.
        pause
    )
    exit /b
)

REM Je MeshCentral agent uz nainstalovan?
sc query "Mesh Agent" >nul 2>&1

if %errorlevel%==0 (
    exit /b 0
)

where curl.exe >nul 2>&1
if errorlevel 1 (
    echo.
    echo "====> Chyba B <===="
    echo Chyba CURL! Nelze spustit.
    echo.
    pause
    exit /b 1
)

set "INSTALATOR=%TEMP%\meshagent64-QuickSupport.exe"

echo.
echo Stahuji instalátor...
curl.exe -fL --progress-bar -o "%INSTALATOR%" "%SERVER%"
if errorlevel 1 (
    echo.
    echo "====> Chyba C <===="
    echo Nepovedlo se stáhnout QuickSupport z URL %SERVER%.
    echo Zkontrolujte prosím připojení k internetu.
    echo.
    pause
    exit /b 1
)

echo.
echo Instaluji agenta...
"%INSTALATOR%" -fullinstall
set "VYSLEDEK=%errorlevel%"

del /f /q "%INSTALATOR%" >nul 2>&1

if not "%VYSLEDEK%"=="0" (
    echo.
    echo "====> Chyba D <===="
    echo Nepovedlo se: instalátor skončil s chybou %VYSLEDEK%.
    echo.
    pause
    exit /b %VYSLEDEK%
)

echo.
echo Hotovo. Stanice je připravená.
echo.
pause